"Advent Informed" by "A. J. Mako"
The story title is "Advent Informed".
The story author is "A. J. Mako".
The story genre is "Religious".
The story headline is "A reimagining of the AAS game 'Advent' by Arthur
Tavistock Jnr."
The story description is "You are but a lowly shepherd boy, tending your
sheep one crisp winter's evening. You have always dreamed of performing
great deeds to the glory of the Lord! But perhaps on this day you may
find more adventure than you bargained for..."
The release number is 1.
The story creation year is 2025.
Release along with cover art, the source text, the library card, and the
"Quixe" interpreter.
Part 1 - Setting Up
Include Basic Combat by A J Mako.
Use scoring.
The maximum score is 100.
After printing the locale description of a room:
if the exits of the location is not empty:
say "Exits: [exits of the location].";
continue the action.
A room has some text called smelldesc.
A room has some text called sounddesc.
A room has a number called roomno.
A room has a number called points. The points of a room is usually 0.
A thing has a number called points. The points of a thing is usually 0.
A thing has a number called weight. The weight of a thing is usually 1.
A thing can be treasure. A thing is usually not treasure.
A thing can be deposited. A thing is usually not deposited.
A room can be indoors or outdoors. A room is usually outdoors.
A room has a list of directions called exits.
msgStoryEnd is "Bad luck, you lost! Perhaps you need to listen more closely
to the Lord's guidance!"
The time of day is 7:13 PM.
When play begins:
say "You are but a lowly shepherd boy, tending your sheep one crisp
winter's evening. You have always dreamed of performing great deeds
to the glory of the Lord! But perhaps on this day you may find more
adventure than you bargained for..."
Part 2 - The Map
Chapter 1 - The Field
The Field is a room.
"Bare, featureless grass stretches in all directions. It's a tough life
being a shepherd sometimes! Still, the lack of distractions gives you
plenty of time to think and pray. You could travel in any direction,
but you know the crossroads is to the east."
The smelldesc is "Mmm, consider the flowers of the field -- they do not
reap and neither do they sow, but they sure do smell nice!"
The sounddesc is "All you can hear is the gentle baaing of happy sheep."
The roomno is 1.
Instead of going nowhere from the Field:
say "You roam aimlessly for a while over the barren scrublands, but
eventually decide to head back to your own field.";
try looking.
After looking in the Field the first time:
move the BrightStar to the field;
say "Suddenly, the angel of the Lord appears! 'Young shepherd,' intones
the angel, 'the Lord has chosen thee for a great task! Today in
Bethlehem a new King is born, who is Christ the Lord! From near and
far people will come to do him homage! But those who have come the
farthest, three wise men of foreign parts, have been ensnared by
Satan, and their gifts stolen! You must recover the three gifts and
deliver them unto the baby Jesus!' You bow down and pray to the
Lord, and promise that you will carry out this quest to the best of
your ability! 'This star shall guide your path,' adds the angel,
pointing at a bright star in the sky. 'May the Lord be with thee!'
And with that, it fades away into nothingness."
Chapter 2 - The Crossroads
The Crossroads is a room.
"You stand at a crossroads, both bodily and spiritually! Where does
your path lead next? And what deeds does the Lord wish you to
perform for His glory? To the north is a large hill, and to the
south you know there's a shrine beside the road. Your flock are
grazing west of here, and the little town of Bethlehem lies to the
east."
The roomno is 7.
The points is 10.
The Crossroads is east of the Field.
Chapter 3 - Bethlehem
Bethlehem is a room.
"For a rustic shepherd, this small town has the appearance of a
bustling metropolis! How ever will you find your path among these
crowds of busy people? A castle dominates the town north of here,
while the market is visible to the south. Going west takes you back
to the crossroads. There is nothing but a lowly stable to the
east."
The sounddesc is "Your ears ache from the incessant noise of a thousand
busy people!"
The smelldesc is "The air of the town is dusty and smells of sweat!"
The roomno is 8.
The points is 10.
Bethlehem is east of the Crossroads.
Chapter 4 - The Stable
The Stable is an indoors room.
"This is but a chilly old stable, but it is filled with the radiance of
the Lord! For Lo!, the saviour hath been born today, and is lying
right here in a manger! Do you have the three gifts yet? If so, lay
them down at the holy child's feet! If not, the exit is west."
The smelldesc is "You breathe deeply of the pungent smells, knowing
that these rude animals are blessed in the sight of the Lord!"
The sounddesc is "Lo! The baby Jesus is awake, but not a tear doth he
shed!"
The roomno is 9999.
The points is 10.
The Stable is east of Bethlehem.
[Treasure Room.]
Chapter 5 - The Market
The Market is a room.
"Even busier than the main part of town, this marketplace is a hive of
frenetic activity! Most of it seems to be centered around the stall
of one particularly [CorruptMerchant]. Narrow streets lead off into
the town in every direction. Only the road north is familiar to
you."
The roomno is 22.
The points is 10.
The Market is south of Bethlehem.
Instead of going nowhere from the Market:
say "You wander aimlessly for a while through the narrow streets of
Bethlehem, and eventually find your way back to the market.";
try looking.
Chapter 6 - The Castle
The Castle is an room.
"This is the castle of the he who is called King of the land -- but, of
course, on this day a King is born who is greater than he! A door
here leads down to the dungeons."
The roomno is 23.
The points is 10.
The Castle is north of Bethlehem.
Chapter 7 - The Dungeon Door
The DungeonDoor is a closed openable locked scenery door.
It is down from the Castle and up from the Dungeon.
The printed name is "dungeon door".
The description is "A heavy wooden door with a tiny barred window."
Understand "dungeon/-- door" as the DungeonDoor.
Chapter 8 - The Dungeon
The Dungeon is an indoors room.
"This smelly dungeon is where he who is called King of the land keeps
his prisoners, many of whom are guilty of nothing more than piety
and holiness! Truly, the Lord shall deliver justice unto the tyrant
when He deems the time to be ripe!"
The sounddesc is "It smells horrible! You pity the poor prisoners who
have to live in such conditions."
The roomno is 26.
The points is 10.
Chapter 9 - The Hillside
The Hillside is a room.
"This hillside is harsh and rocky. Are you sure you are following your
true path by coming to this barren place? You can follow the road
further north, or go south and return to the crossroads."
The roomno is 34.
The points is 10.
The Hillside is north of the Crossroads.
Instead of going nowhere from the Hillside:
if the noun is north:
say "Are you sure you want to follow the road north?";
if the player consents:
say "You follow the road north for days and days,
seeing no sign of the wise men, their gifts, or the
baby Jesus...";
end the story saying "[msgStoryEnd]".
Chapter 10 - The Shrine
The Shrine is a room.
"This is a small shrine by the side of the road, where pilgrims pause
and give thanks to the Lord. You feel the urge to pray! Following
the road north will take you to the crossroads. Going south takes
you into the unknown."
The roomno is 36.
The points is 10.
The Shrine is south of the Crossroads.
Instead of going nowhere from the Shrine:
if the noun is south:
say "Are you sure you want to follow the road south?";
if the player consents:
say "You follow the road south for days and days,
seeing no sign of the wise men, their gifts, or the
baby Jesus...";
end the story saying "[msgStoryEnd]".
Part 3 - Scenery
Chapter 1 - The Star
The BrightStar is a thing.
The printed name is "bright star".
The initial appearance is "A bright star shines in the sky above. It
seems to be leading you [best route from the location to the
Stable]."
The description is "A bright star glimmering in the sky shows you the
direction to the place where the new King hath been born. You must
go [best route from the location to the Stable]!"
It is fixed in place.
Understand "star" or "sky" as the BrightStar.
After going:
if the BrightStar is not in the location and the location is outdoors:
move the BrightStar to the location;
continue the action.
Instead of doing something other than examining with the BrightStar:
say "The star looks very close, but it is very far away."
Part 4 - Props
Chapter 1 - The Shepherd's Robe
The ShepherdsRobe is worn by the player.
The printed name is "shepherd's robe".
The description is "The simple robe of a shepherd, this preserves your
human dignity from the eyes of the world!"
Understand "clothing" or "robe" as the ShepherdsRobe.
Instead of taking off the ShepherdsRobe:
say "You remove your robe. Your face reddens in shame as you feel the
Lord's anger at your immoral nakedness! You quickly pull on your
robe again."
Chapter 2 - The Shepherd's Crook
The ShepherdsCrook is a concussor in the Field.
The printed name is "shepherd's crook".
The description is "This sturdy crook has stood you well over the
years, though sheep may be stuck in hedges and though robbers and
lions may attack your flock, always hath it been a stout
companion!"
The Charges is 2000.
The points is 10.
The hitBonus is 2.
The hurtBonus is 4.
Understand "shepherd/-- crook" as the ShepherdsCrook.
Chapter 3 - The Rusty Key
The RustyKey is a thing.
The printed name is "rusty key".
The description is "It's a heavy key of rusted iron. Who knows what it
might open?"
The points is 10.
The weight is 5.
The RustyKey unlocks the DungeonDoor.
Understand "rusty/-- key" as the RustyKey.
Part 5 - Treasures
Chapter 1 - The Myrrh
The Myrrh is a treasure.
The printed name is "vial of precious myrrh".
The description is "It's a rare sap with a delightful aroma. Truly, a
gift fit for a King!"
The points is 10.
Understand "vial" or "myrrh" as the Myrrh.
Chapter 2 - The Frankincense
The Frankincense is a treasure.
The printed name is "vial of precious frankincense".
The description is "It's a rare kind of sap with a delicious smell. A
gift fit for a King!"
The points is 10.
Understand "vial" or "frankincense" as the Frankincense.
Chapter 3 - The Gold
The ShinyGold is a treasure.
The printed name is "bar of gold".
The description is "See how it gleams! This is surely a treasure worthy
of a King!"
The points is 10.
The weight is 5.
Understand "gold" as the ShinyGold.
Part 6 - Scenes
Chapter 1 - The Myrrh Salesman
The Myrrh Salesman is a scene.
The Myrrh Salesman begins when the location is the Hillside.
The Myrrh Salesman ends when the time since the Myrrh Salesman began is
1 minutes.
When Myrrh Salesman begins:
say "'Thank goodness you[']re here!' says a wizened old man. It[']s one
of the three wise men! 'Satan has stolen my gift of myrrh and
imprisoned it within yonder massive boulder! You must find some way
to release it!'"
When Myrrh Salesman ends:
say "And with that he staggers off."
Chapter 2 - The Spice Trader
The Spice Trader is a scene.
The Spice Trader begins when the location is the Dungeon.
The Spice Trader ends when the time since the Spice Trader began is 1
minute.
When Spice Trader begins:
say "'Thank goodness you[']re here!' cries a wizened old man. It[']s
one of the three wise men! 'I was supposed to take this
frankincense to the new-born King, but the evil tryant was jealous
and threw me in this dungeon. Please, take it for me!'"
When Spice Trader ends:
now the Frankincense is in the location;
say "He drops a vial of frankincense on the floor and staggers out."
Chapter 3 - The Gold Merchant
The Gold Merchant is a scene.
The Gold Merchant begins when the location is Bethlehem and the player
carries a treasure or the player carries the RustyKey.
The Gold Merchant ends when the time since the Gold Merchant began is 1
minute.
When Gold Merchant begins:
say "'Thank goodness you[']re here!' says a wizened old man. It[']s one
of the three wise men! 'The corrupt merchant in the market has
stolen my gift of gold. You must find some way to retrieve it!'"
When Gold Merchant ends:
say "And with that he staggers off."
Chapter 4 - Treasure Room
The Treasury is a scene.
The Treasury begins when the location is the Stable.
The Treasury ends when the number of deposited treasure things is 3.
When Treasury ends:
end the story saying "Congratulations, you won! You are truly blessed
in the eyes of the Lord!"
After dropping a treasure thing in the Stable:
say "You lay [the noun] at the feet of the baby Jesus.";
now the noun is deposited.
Part 7 - Actors
Chapter 1 - The Player
The printed name of the player is "Arthur".
The player is proper-named.
The description of the player is "You are but a humble shepherd, but you are
pure of heart and the Lord doth smile upon thee! Don't let Him down!"
The Health of the player is 40.
The Vitality of the player is 40.
The Fight of the player is 15.
The Evade of the player is 2.
The minDamage of the player is 2.
The maxDamage of the player is 8.
The msgChallenge of the player is "'God on my right hand!' you cry as you
deliver His judgment in the form of a punishing blow!".
The msgPunch of the player is "You swing wildly!"
The msgKick of the player is "You kick violently!"
The msgDodge of the player is "'God on my left hand!' you cry as you ward off
the cruel attack. God[']s blessing falls upon you, and you escape without
injury!"
The msgPain of the player is "'O Lord my God, why hath you forsaken me?' you
cry in anguish as grevious injury is witnessed upon your body!"
The msgDeath of the player is "'O Lord my God, I give my life unto thee, verily
until the last breath!' you gasp piously as the spirit flees your body. God
hears your prayer, and takes you up to sit with Him in His house where all
are welcome!"
Chapter 2 - The Sheep
The Sheep is an animal in the Field.
The printed name is "sheep".
It is ambiguously plural.
The indefinite article is "some".
The description is "The sheep are innocent in the sight of God, and
frolic happily to and fro without a care in the world! Why can't
people be the same way?"
The Vitality is 10.
The Health is 10.
The Fight is 0.
The Evade is 4.
The minDamage is 0.
The maxDamage is 0.
The msgDodge is "The sheep leaps out of the way, bleating alarmedly!
You feel God frown on you!"
The msgPain is "The sheep squeals in pain! You feel God's anger beating
down on you!"
The msgDeath is "Before you can do any more harm to the innocent
creature, God takes it up to His own heavenly pastures where it can
frolic unmolested. How could you hurt such a harmless creature!"
The points is -100.
Understand "sheep" or "flock" as the Sheep.
The fang is a tooth. It is part of the Sheep.
The msgStrike is "The sheep lunges for your neck."
The msgMiss is "The sheep misses you completely."
The msgHit is "The sheep sinks its fangs into your jugular vein!"
Instead of taking the sheep:
say "There are too many of them for you to carry."
Instead of switching on or switching off the Sheep:
say "No. These are not electric sheep."
Before wearing the Sheep:
say "The process of making clothing from the sheep's wool is a long
one, involving skills you do not possess. Besides, you're already
wearing a robe made from a sheep's wool." instead.
Instead of taking off the Sheep:
try taking off the ShepherdsRobe.
Instead of tasting or eating the Sheep:
say "The process of making food from the sheep is a long one, involving
skills you do not possess."
Chapter 3 - The Huge Boulder
[Yes. The huge boulder is an animal only because it's easier to do combat with
an animal than it is with an inanimate rock.]
The HugeBoulder is an animal in the Hillside.
The printed name is "huge boulder".
The description is "One of the gifts you need is imprisoned within this
boulder! How can you possibly get it out?"
The points is 10.
The Vitality is 50.
The Health is 50.
The Fight is 0.
The Evade is 0.
The minDamage is 0.
The maxDamage is 0.
The Corpse is the Myrrh.
The msgPain is "CRACK! A cloud of dust rises up from the boulder as you
smite it!"
The msgDeath is "The Lord gives strength to your arm, and you shatter
Satan's boulder into tiny pieces! A vial of precious myrrh tumbles
out onto the ground, by God's will undamaged by your mighty blow."
Understand "boulder" or "rock" as the HugeBoulder.
[Because we made the boulder an animal to make attacking it easier, we'll have
to make sure the response to any action is appropriate.]
Instead of pulling, pushing, or turning the HugeBoulder:
say "[no budge]."
Instead of pushing the HugeBoulder to:
say "[no budge]."
To say no budge:
say "It [one of]doesn't[or]won't[at random] budge".
Instead of opening or entering the HugeBoulder:
say "There's no door in the boulder. Perhaps there's some way to break
it."
Instead of closing the HugeBoulder:
say "So, you want to close a huge boulder, which is currently not open,
can't be entered, and doesn't have a door?"
Instead of taking the HugeBoulder:
say "You put your hands on the boulder and try to lift it. [no budge]."
Instead of switching on or switching off the HugeBoulder:
say "Nope. It's not the TARDIS."
Instead of taking off, waking, or kissing the HugeBoulder:
say "Rediculous."
Instead of touching or rubbing the HugeBoulder:
say "The huge boulder feels rough, uneven, and solid."
Instead of waving, swinging or dropping the HugeBoulder:
say "But you can't lift it."
Instead of squeezing the HugeBoulder:
say "The huge boulder is quite solid. Squeezing it has no effect."
Instead of burning or cutting the HugeBoulder:
say "You have nothing with which to [parser command so far]."
Instead of tasting the HugeBoulder:
say "The huge boulder tastes like dirt, with a side of moss."
Instead of eating the HugeBoulder:
say "You'll break your teeth!"
After doing anything other than examining with the HugeBoulder for the third time:
if Combat is not happening:
say "Why don't you try SMITEing the boulder. PRAYing might help
too.";
continue the action.
Chapter 4 - The Corrupt Merchant
[In the original game you could only get the gold bar by beating the merchant
with your crook. That is still possible, but you don't get any points for
beating the merchant. Instead you have to pray in the presence of the merchant,
or "pray for merchant's mortal soul". However, praying only works if you ask
the merchant for the gold nicely at least twice.]
The CorruptMerchant is a man in the Market.
The printed name is "corrupt-looking merchant".
The description is "The merchant is clutching a bar of shiny gold!
Surely this is one of the three treasures which rightly belong to
the new King!"
The Vitality is 40.
The Health is 40.
The Fight is 0.
The Evade is 2.
The minDamage is 0.
The maxDamage is 0.
The Corpse is ShinyGold.
The msgDodge is "The merchant cunningly ducks under your blow."
The msgPain is "'Have mercy!' cries the merchant as your punishment
rains down upon him."
The msgDeath is "'Enough, enough!' cries the merchant. 'I repent of my
wicked ways! Here, have your gold!' And he throws the gold to the
floor and runs off in terror! You pray that the Lord shall show him
his true path."
Understand "merchant" or "villain" as the CorruptMerchant.
The CorruptMerchant carries the ShinyGold.
Instead of telling someone about something, try asking the noun about it.
Instead of answering someone that something, try asking the noun about it.
Check an actor asking the CorruptMerchant about:
if the topic understood includes "wise men":
say "'If they[']re so wise,' he says, 'how come I got the gold?'";
rule succeeds;
otherwise if the topic understood includes "bethlehem/market":
say "'Beautiful, isn't it?' he asks. 'You[']re standing in it
right now.'";
rule succeeds;
otherwise if the topic understood includes "christ/jesus/god/lord/savior":
say "'I[']m a materialist,' he says. 'I don[']t believe in all
that spiritual mumbo jumbo.'";
rule succeeds;
otherwise if the topic understood includes "frankincense":
say "'It[']s a rare kind of sap with a delicious smell, if you
care for such things.'";
rule succeeds;
otherwise if the topic understood includes "myrrh":
say "'It[']s a rare sap with a delightful aroma, if you care
for such things.'";
rule succeeds;
otherwise if the topic understood includes "gold":
say "'You can[']t catch me sleepin[']...' he says. 'Don[']t you
ever believe that. I[']m not that dumb. The day you try to
put anything over on me will be a costly one for both of
you...' His face twists into a dangerous, wild, crazed
look. 'Any more lip out of you and I[']ll haul off and let
ya have it. If ya know what[']s good for ya, ya won[']t
monkey around with Fred C. Dobbs.'";
rule succeeds.
Check asking the CorruptMerchant for the ShinyGold for the first time:
say "'I know exactly what you mean,' he says. 'You want to take it all
for yourself and cut me out. I know you for what you are; a long
time I[']ve had my suspicions about you, now I know I[']ve been
right.'";
rule succeeds.
Check asking the CorruptMerchant for the ShinyGold for the second time:
say "'Oh, so that[']s it! Everything[']s clear now. You[']re hopin[']
bandits[']ll get me. That would save you a lot of trouble,
wouldn[']t it? And your conscience wouldn[']t bother you none
neither.'[paragraph break]The man is so consumed with avarice you
feel the urge to pray for his mortal soul.";
now hasAskedForGold is true;
rule succeeds.
Part 8 - Actions
Chapter 1 - Praying
Praying is an action applying to nothing or one topic.
Understand "pray" as praying.
Understand "pray for [text]" as praying.
hasPrayedBefore is initially false.
hasReceivedKey is initially false.
hasAskedForGold is initially false.
hasPrayedForMerchant is initially false.
Check an actor praying (this is the praying before boulders rule):
if the location is the Hillside:
if the HugeBoulder is visible:
now the Fight of the player is 20;
now the minDamage of the player is 12;
now the maxDamage of the player is 18.
Check an actor praying (this is the praying before roadside shrines rule):
if the location is the Shrine:
if the RustyKey is not visible:
move the RustyKey to the Shrine.
Carry out an actor praying (this is the carry out praying rule):
if hasPrayedBefore is false:
increase score by 10;
now hasPrayedBefore is true;
if hasAskedForGold is true and hasPrayedForMerchant is false:
increase score by 10;
now hasPrayedForMerchant is true.
Report an actor praying (this is the report praying rule):
say "You bow your head in silent prayer and ask for guidance in your
quest. [run paragraph on]";
if the minDamage of the player is 12:
say "Your arms feel suddenly stronger.";
otherwise if the location is the Shrine and hasReceivedKey is false:
say "The Lord grants you assistance in your quest: a rusty iron
key appears on the floor in front of you. Whatever can it
be for?";
now hasReceivedKey is true;
otherwise if the location is the Market and the CorruptMerchant is visible:
if hasAskedForGold is true:
now CorruptMerchant is nowhere;
now ShinyGold is in the Market;
say "The Lord grants you assistance in your quest: a
ray of sunshine softens the merchant's blackened
heart. 'I repent of my wicked ways!' the merchant
cries. 'Here, have your gold!' And he throws the
gold to the floor and runs off.";
otherwise:
say paragraph break.
Chapter 2 - Attacking
Understand the command "smite" as "attack".
[You can pray before smiting the rock, which increases your chance to hit and
damage. This just resets these properties to their proper value.]
When Combat ends (this is the restore original properties rule):
if the Combatant is not visible:
if the minDamage of the player is 12:
now the Fight of the player is 15;
now the minDamage of the player is 2;
now the maxDamage of the player is 8;
otherwise if the score is less than 0:
end the story saying "Bad luck, you lost! Perhaps you
need to listen more closely to the Lord's guidance!"
Chapter 3 - Smelling
Check an actor smelling (this is the check smelling rule):
if the location provides the property smelldesc:
if the smelldesc of the location is not empty:
say the smelldesc of the location;
say line break;
rule succeeds.
Chapter 4 - Listening
Check an actor listening (this is the check listening rule):
if the location provides the property sounddesc:
if the sounddesc of the location is not empty:
say the sounddesc of the location;
say line break;
rule succeeds.
Chapter 5 - Dropping
Understand "lay [something] down" as dropping.
Understand "lay down [something]" as dropping.
Chapter 6 - Scoring
After taking something:
if the points of the noun is greater than 0:
increase score by points of the noun;
now points of the noun is 0;
continue the action.
After going:
if the points of the location is greater than 0:
increase score by points of the location;
now points of the location is 0;
continue the action.
Table 1 - Rankings
Score Rank
-100 "Graceless Sinner"
0 "Beginner"
20 "Amateur Adventurer"
40 "Novice Adventurer"
60 "Junior Adventurer"
80 "Adventurer"
100 "Master"
120 "Wizard"
140 "Master Adventurer"
Chapter 7 - Examining Yourself
[
In the original game, the INVENTORY command responds with: "You don't need a
special command to see what you're holding. Just type 'examine me'!"
If you typed EXAMINE ME, the response would be "That makes no sense!" This is
the Interpreter's default parser error. Indeed, the word "examine" is not
recognized by the game. You can only use X ME.
The response to X ME is the player's description, followed by the player's
inventory.
]
Carry out examining (this is the revised examining yourself rule):
if the noun is the player:
say "[description of the noun][paragraph break]";
now examine text printed is true;
say "[We] [are] carrying:[line break]" (A);
list the contents of the player, with newlines, indented,
including contents, giving inventory information, with
extra indentation;
rule succeeds.
The revised examining yourself rule is listed first in the carry out examining rules.
Instead of taking inventory:
say "You don[']t need a special command to see what you[']re holding.
Just type 'examine me'!"
Chapter 8 - Who Am I?
Wondering is an action out of world.
Understand "who am I" or "who me" or "id me" as wondering.
Report an actor wondering:
say "You are [printed name of the player]. [description of the player]
[line break]".
Chapter 9 - About
Abouting is an action out of world.
Understand "about" or "credits" as abouting.
Report an actor abouting:
say "ADVENT INFORMED is a translation into Inform 7 of a game
originally written as part of the Advanced Authoring System hoax
many years ago. You can read more about the hoax here:
https://www.ifwiki.org/AAS.[paragraph break]
The original game, simply called ADVENT, was written by Iain
Merrick as 'Arthur Tavistock Jnr.' You can read slightly more about
the game here: https://www.ifwiki.org/ADVENT_(AAS).[paragraph break]
The translation, by A. J. Mako, brings the original game, with a
few 'improvements,' into the modern world. Why? Because he wanted
to play the game, and the original AAS interpreter is intentionally
buggy, and because the game was just sitting there, not doing
nothing, praying to be translated for wider distribution.[paragraph
break]
The cover art is Linnaea Mallette. It was found at https://www.publ
icdomainpictures.net/en/view-image.php?image=544041&picture=christm
as-nativity-scene-art."
Chapter 10 - Mission
Missioning is an action out of world.
Understand "mission" as missioning.
Understand "what is my mission" as missioning.
Report an actor missioning:
say "You are but a lowly shepherd boy, tending your sheep one crisp
winter's evening. You have always dreamed of performing great deeds
to the glory of the Lord! But perhaps on this day you may find more
adventure than you bargained for...";
say line break;
say "Suddenly, the angel of the Lord appears! 'Young shepherd,' intones
the angel, 'the Lord has chosen thee for a great task! Today in
Bethlehem a new King is born, who is Christ the Lord! From near and
far people will come to do him homage! But those who have come the
farthest, three wise men of foreign parts, have been ensnared by
Satan, and their gifts stolen! You must recover the three gifts and
deliver them unto the baby Jesus!' You bow down and pray to the
Lord, and promise that you will carry out this quest to the best of
your ability! 'This star shall guide your path,' adds the angel,
pointing at a bright star in the sky. 'May the Lord be with thee!'
And with that, it fades away into nothingness."
Chapter 11 - XYZZY
xyzzying is an action out of world.
Understand "xyzzy" as xyzzying.
Report an actor xyzzying:
say "No. No. No. That's the [italic type]other[roman type] ADVENT."
Chapter 12 - ZORK
zorking is an action out of world.
understand "zork" as zorking.
Report an actor zorking:
say "Beannachd leat."
