"The Black Knight" by "A. J. Mako"
The story headline is "Do you have what it takes to face the Black Knight?".
The story genre is "Comedy".
The story creation year is 2019.
The release number is 1.
The story description is "This is an adaptation of the scene from Monty
Python and the Holy Grail, used exclusively as a learning exercise."
[Change Log:
Release 1 (2019-11-24)
]
Include Epistemology by Eric Eve.
Include Basic Screen Effects by Emily Short.
Part 1 - Globals
A person has a number called maximum hit points.
A person has a number called current hit points.
The maximum hit points of the player is 100.
Definition: a person is dead if his current hit points are less than 0.
Definition: a person is other if it is not the player.
Definition: a thing is selfish if it is part of the player and the player can
see an other person.
Knight-status is a kind of value.
The knight-statuses are invincible, battling, fighting, revenging, kicking,
hopping, taunting.
The description of the player is "As resplendent as ever in [our] regalia as
Arthur, King of the Britons."
Part 2 - Start Up
When play begins:
repeat with victim running through people:
now the current hit points of the victim is the maximum hit points of
the victim;
say "[bold type]The story thus far...[roman type][paragraph break]
Arthur, son of Uther Pendragon, from the castle of Camelot, King of the
Britons, defeater of the Saxons, sovereign of all England has ridden the
length and breadth of the land in search of knights who will join him at
the court of Camelot. He has ridden since the snows of winter covered
the land, found a coconut, argued about the airspeed velocity of unladen
swallows, mistook a young man for an old woman, gotten a lesson in
political philosophy, and repressed a peasant.[paragraph break]Now...";
pause the game.
Part 3 - The Map
Chapter 1 - Rooms
The Road is a room. The description is "The road twists and winds through the
forest. It's not really much of a road [unicode 8211] more like a path. For
a Medieval road, however, it's a veritable King's Highway. It lacks only a
pair of shrubberies. From here the road comes from the northeast and
continues south."
The Place is a room. The description is "The road opens into a wide clearing
and across a low, wooden bridge before re-entering the forest. Curiously,
a clump of large trees sit to the left of the bridge on this side of it.
And another clump of large trees sit to the right of the bridge on the
other side of it. A small creek winds its way through the scene."
It is south of the Road.
The Beyond is a room. The description is "The road twists and winds through the
forest. Not much has changed about it, but it seems it cries out even more
for a pair of shrubberies. [We] can continue south."
The Bridge is a door. It is scenery, open and unopenable. The description is
"While it's well-built and solid-looking, it's not much of a bridge. It
spans what amounts to a two-foot-deep ditch."
The Bridge is south of the Place and north of the Beyond.
Chapter 2 - Scenery
The forest is a backdrop. The descriptoin is "Deciduous trees and underbrush
obscure the horizon in all directions."
The forest is everywhere.
Understand "trees" as the forest.
The path is a backdrop. The descriptoin is "Built using the latest
road-building technologies, the road is basically bare dirt trampled under
several feet."
The path is everywhere.
Understand "road", "dirt", "highway" or "path" as the path.
The clearing is a backdrop in the Place. The description is "A wide, mostly
open area straddling the road here. [We] might even call it a lay-by, if
such a thing existed."
The left clump is scenery. The description is "Not a clump really, it's just a
pair of large oaks providing shade to the far side of the bridge."
It is in the Place.
Understand "left", "clump", "of", "large", or "trees" as the left clump.
The right clump is scenery. The description is "Okay, maybe it was a clump when
it was younger. Now it's just a very large and squat oak tree providing
shade to the near side of the bridge."
It is in the Place.
Understand "right", "clump", "of", "large", or "trees" as the right clump.
The creek is a backdrop in the Place. The description is "Little more than a
trickle, the creek gurgles a winding path through the forest and the
clearing at the bottom of a shallow, two-foot-deep ditch."
Understand "ditch" as the creek.
The shrubberies is a backdrop. It is everywhere.
Understand "shrub" or "bush" or "bushes" as the shrubberies.
Instead of examining the shrubberies:
if the player is in the Road, say "[We] [can't] see any such thing.";
otherwise say "[We] know there has to be a shrubbery out there somewhere.
Unfortunately, [we] still [can't] see any such thing."
Chapter 3 - Characters
Section 1 - The Black Knight
The Black Knight is a man in the Place.
The initial appearance is "[blackguard appears]."
The description of the Black Knight is "[describe blackguard]."
The maximum hit points of the Black Knight is 100.
The black knight has a knight-status called current status.
To say describe blackguard:
if the current status of the black knight is:
-- invincible:
say "Clad in black armor from the top of his tall pot helmet to the
tips of his pointed armored shoes, this knight looks quite
formidable";
-- battling:
say "Clad in black armor from the top of his tall pot helmet to the
tips of his pointed armored shoes, wielding a dirty big sword,
this knight looks quite formidable";
-- fighting:
say "Clad in black armor from the top of his tall pot helmet to the
tips of his pointed armored shoes, wielding a dirty big sword,
this knight looks quite formidable";
-- revenging:
say "Still clad in black armor from the top of his tall pot helmet
to the tips of his pointed armored shoes, the knight still
wields his dirty big sword. It's just his left arm is missing";
-- kicking:
say "Still clad in black armor from the top of his tall pot helmet
to the tips of his pointed armored shoes, the knight is
literally disarmed [unicode 8211] both arms are missing";
-- hopping:
say "Still clad in black armor from the top of his tall pot helmet
to the tips of his pointed armored shoe, the knight hops on one
leg [unicode 8211] the other leg and both arms are missing";
-- taunting:
say "The knight is just a head and torso sitting on the ground. Not
very formidable any more".
To say blackguard appears:
if the current status of the black knight is:
-- invincible:
say "[We] can see an imposing knight in black armor";
-- battling:
say "[We] can see an imposing knight in black armor, wielding a
dirty big sword";
-- fighting:
say "[We] can see an imposing knight in black armor, angrily
wielding a dirty big sword";
-- revenging:
say "[We] can see an imposing one-armed knight in black armor,
violently wielding a dirty big sword";
-- kicking:
say "[We] can see a no-armed knight in black armor";
-- hopping:
say "[We] can see a hopping one-legged, no-armed knight in black
armor";
-- taunting:
say "[We] can see the head and torso of a knight in black armor".
Section 2 - The Green Knight
The Green Knight is a thing in the Place.
The printed name is "heap of red speckled green rags".
The indefinite article is "a".
The description is "This is the twisted and mangled corpse of the Green Knight.
There's a hole the size of [our] fist in the face of his helmet, and a
bright red liquid still seeps from it."
Understand "heap of green rags" or "mangled/twisted corpse" as the Green Knight.
After examining the Green Knight:
Now the printed name of the Green Knight is "Green Knight's mangled corpse";
Now the indefinite article of the Green Knight is "the".
Before taking the Green Knight:
say "[one of]I can't imagine what [we][']d need that for[or]He's dead Jim,
er Dave, er Arthur[or][The noun] doesn't want to join [our] Knights of
the Round Table[then at random].";
stop the action.
Chapter 4 - Things
The coconut is a thing. The description is "There are two halves to this coconut."
The player carries it.
[These are all bits of the Black Knight that will be chopped off, eventually]
The Right Arm is a thing. The printed name is "right arm".
The description is "This is the Black Knight's right arm, which has been neatly
severed at the shoulder. Its fingers still deftly grasp the Black Knight's
sword."
The indefinite article of the Right Arm is "someone's".
The Left Arm is a thing. The printed name is "left arm".
The description is "This is the Black Knight's left arm, which has been neatly
severed at the shoulder."
The indefinite article of the Left Arm is "someone's".
The Right Leg is a thing. The printed name is "right leg".
The description is "This is the Black Knight's right leg, which has been neatly
severed at mid-thigh."
The indefinite article of the Right Leg is "someone's".
The Left Leg is a thing. The printed name is "left leg".
The description is "This is the Black Knight's left leg, which has been neatly
severed at mid-thigh."
The indefinite article of the Left Leg is "someone's".
The Black Corpse is a thing. The printed name is "corpse".
The description is "This is the Black Knight's legless and armless corpse."
The indefinite article of the Black Corpse is "someone's".
Understand "black" and "knight" as the Black Corpse.
After examining something:
if the noun is:
-- the Right Arm:
Now the printed name of the Right Arm is "Black Knight's right arm";
Now the indefinite article of the Right Arm is "the";
-- the Right Leg:
Now the printed name of the Right Leg is "Black Knight's right leg";
Now the indefinite article of the Right Leg is "the";
-- the Left Arm:
Now the printed name of the Left Arm is "Black Knight's left arm";
Now the indefinite article of the Left Arm is "the";
-- the Left Leg:
Now the printed name of the Left Leg is "Black Knight's left leg";
Now the indefinite article of the Left Leg is "the";
-- the Black Corpse:
Now the printed name of the Black Corpse is "Black Knight's corpse";
Now the indefinite article of the Black Corpse is "the";
Before taking something:
if the noun is the Right Arm or the noun is the Right Leg or the noun is the
Left Arm or the noun is the Left Leg or the noun is the Black Corpse:
say "[one of]I can't imagine what [we][']d need that for[or]We can't
rebuild him. We don't have the technology[or]Chivalry won't allow
[us] to beat up the Black Knight with his own [noun]
[then at random].";
stop the action.
Chapter 5 - Weapons
A weapon is a kind of thing.
A weapon has a number called the maximum damage.
The maximum damage of a weapon is usually 4.
A fist is a kind of weapon. A fist is part of every person.
The maximum damage of a fist is usually 1.
A boot is a kind of weapon. A boot is part of every person.
The maximum damage of a boot is usually 1.
The Black Knight carries a weapon called a bastard sword.
The maximum damage of the bastard sword is 8.
The player carries a weapon called a shining sword.
The maximum damage of the shining sword is 8.
The printed name of the shining sword is "shining sword".
The shining sword is proper-named.
The description of the shining sword is "[first time]Excalibur! [only]A large,
well-made and highly polished sword with a design of two chimeras on the
golden hilt. When unsheathed, the blade appears to come from the mouths of
the two chimeras like two flames of fire, so dreadful it is difficult for
anyone to look."
Understand "shining/polished/bright sword" or "excalibur" or "sword" as the
shining sword.
After examining the shining sword:
Now the printed name of the shining sword is "Excalibur";
Now the indefinite article of the shining sword is "the".
Does the player mean doing something when the noun is a selfish fist or the
second noun is a selfish fist: it is very likely.
Does the player mean doing something when the noun is a selfish boot or the
second noun is a selfish boot: it is very likely.
Does the player mean doing something when the noun is a not selfish fist or
the second noun is a not selfish fist: it is very unlikely.
Does the player mean doing something when the noun is a not selfish boot or
the second noun is a not selfish boot: it is very unlikely.
Part 4 - Operations
Chapter 1 - Going
Instead of going nowhere:
if the noun is up:
say "It's not likely [we][']ll find suitable knights to join [our]
court up in the trees.";
otherwise if the noun is down:
say "[We] could dig all the way to China before [we][']d find a
suitable knight to join [our] court down there.";
otherwise if the noun is northeast and the location is the Road:
say "That's the way [we] came. [We] didn't find any suitable knights
to join [our] court that way.";
otherwise if the noun is southeast or the noun is southwest and the
location is the Place:
try entering the bridge;
otherwise if the noun is south and the location is the Beyond:
end the game victoriously;
otherwise:
say "There is nothing wrong with the road that [we] need to start
building a bypass."
Before going south to The Place the first time:
say "Approaching a bridge [we] must cross, [we] [are] alerted to the sounds
of nearby battle. [We] see two knights in mortal combat [unicode 8211]
one clad in the blackest armor, and one clad in a drab, olive green
armor. The battle is ferocious, and it is unclear which will prevail,
and which [we] should root for. Finally, the Black Knight thrusts his
sword though the Green Knight's helmet and prevails.[paragraph break]
Please press SPACE to continue.";
wait for the SPACE key.
Instead of going south from the Place, try entering the bridge.
Before entering the bridge:
If the current status of the Black Knight is invincible:
say "'None shall pass,' the Black Knight says in a deep, echoey voice."
instead;
otherwise if the current status of the Black Knight is not taunting:
say "'None shall pass,' the Black Knight says perilously." instead;
otherwise:
if the Black Knight is not nowhere:
say "The Black Knight yells after [us], 'Oh, I see, running away,
heh? You yellow chicken. Come back here and take what's coming
to you. I'll bite your legs off.'".
Before going north during the Combat:
if the current status of the Black Knight is not taunting:
say "'None shall pass,' the Black Knight says in a deep, echoey voice."
instead;
otherwise if the current status of the Black Knight is taunting:
say "The Black Knight yells after [us], 'Oh, I see, running away, heh?
You yellow chicken. Come back here and take what's coming to you.
I'll bite your legs off.'".
Chapter 2 - Talking
The block answering rule is not listed in any rulebook.
Understand "say to [someone] [text]" as answering it that.
Check answering it that:
if the current status of the black knight is invincible:
if "[the topic understood]" matches the text "cross" or
"[the topic understood]" matches the text "bridge":
say "'Then you shall die,' the Black Knight intones ominously."
instead;
otherwise if "[the topic understood]" matches the text "stand aside":
say "'I move for no man,' the Black Knight advises threateningly."
instead;
otherwise if "[the topic understood]" matches the text "what":
say "'None shall pass,' the Black Knight says dangerously."
instead;
otherwise:
say "The Black Knight stands silently, [one of]guarding the bridge
[or]ignoring [us][at random]." instead;
otherwise:
if the current status of the black knight is:
-- battling:
say "The Black Knight stands in a defensive position, [one of]
guarding the bridge[or]ignoring [us][at random]." instead;
-- fighting:
say "The Black Knight stands in a defensive position, [one of]
guarding the bridge[or]ignoring [us][at random]." instead;
-- revenging:
if "[the topic understood]" matches the text "stand aside":
say "'[']Tis but a scratch,' the Black Knight says.";
otherwise if "[the topic understood]" matches the text "arm's
off":
say "The Black Knight feints, saying 'No it isn't.'";
otherwise:
say "'[one of]I've had worse.[no line break][or]C'mon ya
pansy![no line break][or]Have'at'chew![no line break]
[then purely at random]' the Black Knight says.";
-- kicking:
if "[the topic understood]" matches the text "no arms":
say "'Yes I have,' The Black Knight says determinedly.";
otherwise:
say "'[one of]C'mon then![no line break][or]Have'at'chew!
[no line break][or]Oh, had enough eh?[no line break][or]
It's just a flesh wound.[no line break][or]Chicken,
chicken![no line break][then purely at random]' the
Black Knight says.";
-- hopping:
say "'[one of]I'm invincible![no line break][or]The Black Knight
always triumphs![no line break][or]Have'at'chew!
[no line break][or]C'mon then![no line break]
[then purely at random]' the Black Knight says.";
-- taunting:
say "'I'll bite your legs off.' the Black Knight says.".
Chapter 3 - Attacking
The block attacking rule is not listed in any rulebook.
Understand the commands "attack" or "punch" or "kill" as something new.
Understand the commands "hit" or "thump" or "break" as something new.
Understand the commands "destroy" or "murder" or "torture" as something new.
Understand the commands "smash" and "wreck" as something new.
Attacking it with is an action applying to one visible thing and one thing.
Understand "attack [something] with [something]" as attacking it with.
Understand the commands "destroy" and "kill" and "murder" as "attack".
Understand the commands "hit" and "break" and "smash" as "attack".
Understand the commands "torture" and "wreck" as "attack".
The attacking it with action has a number called the damage inflicted.
Setting action variables for attacking something with something:
if the second noun is a weapon:
let the maximum attack be the maximum damage of the second noun;
now the damage inflicted is a random number between 1 and the maximum
attack.
Check an actor attacking something with something (this is the attacking with
a fist is punching rule):
if the second noun is a fist, try punching the noun instead.
Check an actor attacking something with something (this is the attacking with a
boot is kicking rule):
if the second noun is a boot, try kicking the noun instead.
Check an actor attacking something with something (this is the can't attack
shrubberies rule):
if the noun is the shrubberies:
say "[We] [can't] see any such thing." instead.
Check an actor attacking something with something (this is the can't attack
things that aren't there rule):
if the noun is not visible:
say "[We] [can't] see any such thing." instead.
Check an actor attacking something with something (this is the can't attack
scenery rule):
if the noun is scenery:
if the actor is the player, say "[The noun] is not something that can be
attacked." instead.
Check an actor attacking something with something (this is the can't attack with
something that isn't a weapon rule):
if the second noun is not a weapon:
if the actor is the player, say "[The second noun] does not qualify as a
weapon." instead.
Check an actor attacking something with something (this is the can't attack a
non-person rule):
if the noun is not a person:
if the actor is the player, say "[The noun] has no life to lose."
instead.
Carry out an actor attacking something with something (this is the standard
attacking it with a weapon rule):
decrease the current hit points of the noun by the damage inflicted;
if the noun is dead:
if the noun is the Black Knight:
now the Black Corpse is in the place;
now the noun is nowhere.
Report attacking a dead person with something (this is the death-report priority
rule):
say "[We] attack with [the second noun], killing [the noun]!" instead.
Report attacking someone with something (this is the normal attacking report
rule):
say "[We] attack [the noun] with [the second noun], causing
[damage inflicted] point[s] of damage!" instead.
Report someone attacking the player with something when the player is dead (this
is the player's-death priority rule):
say "[The actor] attacks [us] with [the second noun], finishing [us] off!";
end the game deceased;
stop the action
Report someone attacking the player with something (this is the standard report
someone attacking the player with rule):
say "[The actor] attacks [us] with [the second noun], causing
[damage inflicted] point[s] of damage!" instead.
Report someone attacking something with something (this is the standard report
attacking it with rule):
say "[The actor] attacks [the noun] with [the second noun], causing
[damage inflicted] point[s] of damage!" instead.
Chapter 4 - Punching
Punching is an action applying to one visible thing.
Understand "punch [something]" as punching.
The punching action has a number called the damage caused.
Setting action variables for punching something:
If the noun is a person:
let the maximum attack be the maximum damage of a random fist which is
part of the actor;
now the damage caused is a random number between 1 and the maximum
attack.
Check an actor punching (this is the can't punch shrubberies rule):
if the noun is the shrubberies:
say "[We] [can't] see any such thing." instead.
Check an actor punching (this is the can't punch things that aren't there
rule):
if the noun is not visible:
say "[We] [can't] see any such thing." instead.
Check an actor punching (this is the can't punch scenery rule):
if the noun is scenery:
if the actor is the player, say "[The noun] is not something that can
be punched." instead.
Check an actor punching (this is the can't punch a non-person rule):
if the noun is not a person:
if the actor is the player, say "[The noun] has no reaction to [our]
punch." instead.
Carry out an actor punching (this is the standard punching rule):
decrease the current hit points of the noun by the damage caused;
if the noun is dead:
if the noun is the Black Knight:
now the Black Corpse is in the place;
now the noun is nowhere.
Report punching a dead person (this is the punching death-report priority
rule):
say "[We] punch, killing [the noun]!" instead.
Report punching someone (this is the normal punching report rule):
say "[We] punch [the noun], causing [damage caused] point[s] of damage!"
instead.
Report someone punching the player when the player is dead (this is the punching
player's-death priority rule):
say "[The actor] punches [us], finishing [us] off!";
end the game deceased;
stop the action.
Report someone punching the player (this is the standard report someone punching
the player rule):
say "[The actor] punches [us], causing [damage caused] point[s] of damage!"
instead.
Report someone punching something (this is the standard report punching rule):
say "[The actor] punches [the noun], causing [damage caused] point[s] of
damage!" instead.
Chapter 5 - Kicking
Kicking is an action applying to one visible thing.
Understand "kick [something]" as kicking.
The kicking action has a number called the damage produced.
Setting action variables for kicking something:
if the noun is a person:
let the maximum attack be the maximum damage of a random boot which is
part of the actor;
now the damage produced is a random number between 1 and the maximum
attack.
Check an actor kicking (this is the can't kick shrubberies rule):
if the noun is the shrubberies:
say "[We] [can't] see any such thing." instead.
Check an actor kicking (this is the can't kick things that aren't there rule):
if the noun is not visible:
say "[We] [can't] see any such thing." instead.
Check an actor kicking (this is the can't kick scenery rule):
if the noun is scenery:
if the actor is the player, say "[The noun] is not something that can
be kicked." instead.
Check an actor kicking (this is the can't kick a non-person rule):
if the noun is not a person:
if the actor is the player, say "[The noun] has no reaction to [our]
kick." instead.
Carry out an actor kicking (this is the standard kicking rule):
decrease the current hit points of the noun by the damage produced;
if the noun is dead:
if the noun is the Black Knight:
now the Black Corpse is in the place;
now the noun is nowhere.
Report kicking a dead person (this is the kicking death-report priority rule):
say "[We] kick, killing [the noun]!" instead.
Report kicking someone (this is the normal kicking report rule):
say "[We] kick [the noun], causing [damage produced] point[s] of damage!"
instead.
Report someone kicking the player when the player is dead (this is the kicking
player's-death priority rule):
say "[The actor] kicks [us], finishing [us] off!";
end the game deceased;
stop the action.
Report someone kicking the player (this is the standard report someone kicking
the player rule):
say "[The actor] kicks [us], causing [damage produced] point[s] of damage!"
instead.
Report someone kicking something (this is the standard report kicking rule):
say "[The actor] kicks [the noun], causing [damage produced] point[s] of
damage!" instead.
Chapter 6 - Combat
Before the player attacking the black knight with something:
If the current status of the Black Knight is invincible:
now the current status of the Black Knight is battling.
The Combat is a scene.
The Combat begins when the current status of the Black Knight is battling.
The Combat ends when the current status of the Black Knight is taunting.
When the Combat begins:
now the left hand status line is "Black Knight
([current status of the black knight]):
[current hit points of the black knight]";
now the right hand status line is "King Arthur:
[current hit points of player]";
say "Now the battle begins!"
Every turn during the Combat:
if "[the action name part of the current action]" matches the text
"attacking":
if the actor is the player:
if the current status of the Black Knight is:
-- battling:
if the current hit points of the Black Knight is less than
75, now the current status of the Black Knight is
fighting;
-- fighting:
if the current hit points of the Black Knight is less than
55:
now the Left Arm is in the place;
now the current status of the Black Knight is revenging;
say "[Our] strike severs the Black Knight's left arm at
the shoulder. It flops to the ground in a gush of
blood.";
-- revenging:
if the current hit points of the Black Knight is less than
40:
now the Right Arm is in the place;
now the bastard sword is in the place;
now the current status of the Black Knight is kicking;
say "[Our] strike severs the Black Knight's right arm
at the shoulder. It flops to the ground in a gush
of blood.";
-- kicking:
if the current hit points of the Black Knight is less than
25:
now the Right Leg is in the place;
now the current status of the Black Knight is hopping;
say "[Our] strike severs the Black Knight's right leg
off at the thigh. It flops to the ground in a gush
of blood.[paragraph break]'Right, I'll do you for
that!' the Black Knight says.[paragraph break]";
-- hopping:
if the current hit points of the Black Knight is less than
10:
now the Left Leg is in the place;
now the current status of the Black Knight is taunting;
say "[Our] strike severs the Black Knight's left leg
off at the thigh. It flops to the ground in a gush
of blood.[paragraph break]'Alright, we'll call it
a draw.' the Black Knight says.";
-- taunting:
if the current hit points of the Black Knight is less than
0:
now the current hit points of the Black Knight is 1;
if the current status of the black knight is not taunting:
if the black knight carries a weapon:
try the black knight attacking the player with a random
weapon which is carried by the black knight;
otherwise if the current status of the black knight is kicking:
try the black knight kicking the player;
otherwise if the current status of the black knight is hopping:
say "The Black Knight [one of]hops at [us][or]bleeds on
[us][at random]."
Chapter 7 - Ending The Game
To end the game victoriously:
end the story saying "Congratulations! [Our] efforts to establish the
Knights of the Round Table can continue!".
To end the game deceased:
end the story saying "[WE] HAVE DIED. At first, [we] think 'Maybe it was
all just a bad dream,' but no such luck. It appears to be for real.
That[']s too bad, although something gnawing on [our] tongue thinks
it's pretty wonderful, or at least fairly tasty."
Part 5 - Cheating & Stuff
Chapter 1 - Diagnosis
[This is a command to see the health of a specific character. It is unnecessary
since the information is provided in the status bar.]
Diagnosing is an action applying to one visible thing.
Understand "diagnose [something]" as diagnosing.
Check diagnosing:
if the noun is not a person, say "Only people can have diagnoses." instead.
Carry out diagnosing:
say "[if the noun is the player][We] have[otherwise][The noun] has[end if]
[current hit points of the noun] out of a possible
[maximum hit points of the noun] hit points remaining."
Chapter 2 - Healing
[This cheat lets you magically heal a character. It was created for debugging
Arthur's death, but it works like the Ctrl+R cheat key in Baldur's Gate, so
we're keeping it.]
Healing is an action applying to one visible thing.
Understand "heal [something]" as healing.
Check healing:
if the noun is not a person, say "Only people can be healed." instead.
Carry out healing:
now the current hit points of the noun is the maximum hit points of the
noun;
say "I have restored [The noun] to full hit points."
Chapter 3 - Cheating
[CLUAConsole: this is the cheat system within Baldur's Gate.]
Section 1 - Change Excalibur Damage
[The player is meant to type "CLUAConsole: ExcaliburDamage() N". Case is not
important, nor is the punctuation.]
Understand "cluaconsole excaliburdamage [number]" as cheat1ing.
Cheat1ing is an action applying to a number.
Carry out cheat1ing:
now the maximum damage of the shining sword is the number understood;
say "Cheating accomplished."
Section 2 - Change Bastard Sword Damage
[The player is meant to type "CLUAConsole: SwordDamage() N". Case is not
important, nor is the punctuation.]
Understand "cluaconsole sworddamage [number]" as cheat2ing.
Cheat2ing is an action applying to a number.
Carry out cheat2ing:
now the maximum damage of the bastard sword is the number understood;
say "Cheating accomplished."
Section 3 - The Great Gonzo
[TheGreatGonzo() is a Baldur's Gate cheat that summons 10 killer chickens who
will defend you. Here they're a way to kill the Black Knight with a single
command. The player is meant to type "CLUAConsole: TheGreatGonzo()". Case is
not important, nor is the punctuation.]
Gonzoing is an action applying to nothing.
Understand "cluaconsole thegreatgonzo" as gonzoing.
Carry out gonzoing:
say "Ten killer chickens appear at [our] feet to defend [us]. [no line break]";
if the black knight is visible:
say "They immediately attack the Black Knight, killing him.";
now the current hit points of the black knight is -1;
now the black corpse is in the place;
now the black knight is nowhere;
otherwise:
say "They quickly become bored and wander away."
